Re: [NEWBIE] Windows SYSLOG

From: Steve (sbryant1@carolina.rr.com)
Date: 07/03/02


> Chris Clos
>
> Does anyone have a Windows 32 version setup using a good
> SYSLOG rotation
> like the unix version has?
I have Win98 and Win2k versions of Autorun originally created
by Matt Houston.

-------------
Win98 version
-------------
@ECHO OFF
echo Win/DOS Autorun for CircleMUD!
echo.
echo This small batch file was created by Matt Houston. No need to
echo include him in the Credits, but if you wish to, it is okay with
echo me. This may or may not be the last version.
echo.

set Path=C:\Windows\Command
set PORT=25
set FLAGS=-q
set CDIR=c:\circle\bin

:main

  echo.
  echo autorun starting game >> Log\Syslog.txt
  echo autorun starting game
  echo running %CDIR%\circle.exe %FLAGS% %PORT% >> Log\Syslog.txt
  echo running %CDIR%\circle.exe %FLAGS% %PORT%

  start /w /m %CDIR%\circle.exe %FLAGS% %PORT%

  echo MUD life cycle ended...  Cleaning up... >> Log\Syslog.txt
  echo MUD life cycle ended...  Cleaning up...

  find "self-delete"    Log\Syslog.txt >> Log\Delete.txt
  find "death trap"     Log\Syslog.txt >> Log\DeadTrap.txt
  find "killed"         Log\Syslog.txt >> Log\Rip.txt
  find "Running"        Log\Syslog.txt >> Log\Restarts.txt
  find "advanced"       Log\Syslog.txt >> Log\Levels.txt
  find "equipment lost" Log\Syslog.txt >> Log\RentGone.txt
  find "usage"          Log\Syslog.txt >> Log\Usage.txt
  find "new player"     Log\Syslog.txt >> Log\NewPlay.txt
  find "SYSERR"         Log\Syslog.txt >> Log\Errors.txt
  find "(GC)"           Log\Syslog.txt >> Log\ImpCmds.txt
  find "Bad PW"         Log\Syslog.txt >> Log\BadPws.txt

  move Log\Syslog5.txt    Log\Syslog6.txt
  move Log\Syslog4.txt    Log\Syslog5.txt
  move Log\Syslog3.txt    Log\Syslog4.txt
  move Log\Syslog2.txt    Log\Syslog3.txt
  move Log\Syslog1.txt    Log\Syslog2.txt
  move Log\Syslog.txt     Log\Syslog1.txt
  echo Beginning of Syslog >> Log\Syslog.txt

  if exist .fastboot   goto fastboot
  if exist .killscript goto kill
  if exist pause       goto pause

:default
  echo Rebooting!
  goto main

:fastboot
  del .fastboot
  echo Rebooting!
  goto main

:kill
  del .killscript
  echo. >> Log\Syslog.txt
  echo.
  echo MUD is now shutdown.
  goto end

:pause
  echo Autorun paused, hit any key to continue.
  pause > nul
  del pause
  goto main

:end
  echo.
  echo Thank you for using Win/DOS Autorun for CircleMUD!
  echo Created by Matt Houston.
  echo.

-------------
Win2k version
-------------
@ECHO OFF
echo Win/DOS Autorun for CircleMUD!
echo.
echo This small batch file was created by Matt Houston. No need to
echo include him in the Credits, but if you wish to, it is okay with
echo me. This may or may not be the last version.
echo.

set Path=C:\Win2000\system32
set PORT=25
set FLAGS=-q
set CDIR=c:\circle\bin

:main

  echo.
  echo autorun starting game >> Log\Syslog.txt
  echo autorun starting game
  echo running %CDIR%\circle.exe %FLAGS% %PORT% >> Log\Syslog.txt
  echo running %CDIR%\circle.exe %FLAGS% %PORT%

  start "CircleMUD" /wait /min %CDIR%\circle.exe %FLAGS% %PORT%

  echo MUD life cycle ended...  Cleaning up... >> Log\Syslog.txt
  echo MUD life cycle ended...  Cleaning up...

  find "self-delete"    Log\Syslog.txt >> Log\Delete.txt
  find "death trap"     Log\Syslog.txt >> Log\DeadTrap.txt
  find "killed"         Log\Syslog.txt >> Log\Rip.txt
  find "Running"        Log\Syslog.txt >> Log\Restarts.txt
  find "advanced"       Log\Syslog.txt >> Log\Levels.txt
  find "equipment lost" Log\Syslog.txt >> Log\RentGone.txt
  find "usage"          Log\Syslog.txt >> Log\Usage.txt
  find "new player"     Log\Syslog.txt >> Log\NewPlay.txt
  find "SYSERR"         Log\Syslog.txt >> Log\Errors.txt
  find "(GC)"           Log\Syslog.txt >> Log\ImpCmds.txt
  find "Bad PW"         Log\Syslog.txt >> Log\BadPws.txt

  move Log\Syslog5.txt    Log\Syslog6.txt
  move Log\Syslog4.txt    Log\Syslog5.txt
  move Log\Syslog3.txt    Log\Syslog4.txt
  move Log\Syslog2.txt    Log\Syslog3.txt
  move Log\Syslog1.txt    Log\Syslog2.txt
  move Log\Syslog.txt     Log\Syslog1.txt
  echo Beginning of Syslog >> Log\Syslog.txt

  if exist .fastboot   goto fastboot
  if exist .killscript goto kill
  if exist pause       goto pause

:default
  echo Rebooting!
  goto main

:fastboot
  del .fastboot
  echo Rebooting!
  goto main

:kill
  del .killscript
  echo. >> Log\Syslog.txt
  echo.
  echo MUD is now shutdown.
  goto end

:pause
  echo Autorun paused, hit any key to continue.
  pause > nul
  del pause
  goto main

:end
  echo.
  echo Thank you for using Win/DOS Autorun for CircleMUD!
  echo Created by Matt Houston.
  echo.

--
   +---------------------------------------------------------------+
   | FAQ: http://qsilver.queensu.ca/~fletchra/Circle/list-faq.html |
   | Archives: http://post.queensu.ca/listserv/wwwarch/circle.html |
   | Newbie List:  http://groups.yahoo.com/group/circle-newbies/   |
   +---------------------------------------------------------------+



This archive was generated by hypermail 2b30 : 06/25/03 PDT